1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
|
// =================================================================================================
// This file is part of the CLBlast project. The project is licensed under Apache Version 2.0. This
// project loosely follows the Google C++ styleguide and uses a tab-size of two spaces and a max-
// width of 100 characters per line.
//
// Author(s):
// Cedric Nugteren <www.cedricnugteren.nl>
//
// This file contains the Xgemv kernel (generic version) for matrix-vector multiplication.
//
// =================================================================================================
// Enables loading of this file using the C++ pre-processor's #include (C++11 standard raw string
// literal). Comment-out this line for syntax-highlighting when developing.
R"(
// =================================================================================================
// Parameters set by the tuner or by the database. Here they are given a basic default value in case
// this kernel file is used outside of the CLBlast library.
// 1: For the full version of the kernel
#ifndef WGS1
#define WGS1 64 // The local work-group size
#endif
#ifndef WPT1
#define WPT1 1 // The amount of work-per-thread
#endif
#ifndef UNROLL1
#define UNROLL1 32 // Unroll factor (must be a divider of WGS1)
#endif
// 2 and 3: For the fast versions, see 'xgemv_fast.opencl'
// =================================================================================================
// Defines how to load the input matrix in the non-vectorized case
INLINE_FUNC real LoadMatrixA(const __global real* restrict agm, const int x, const int y,
const int a_ld, const int a_offset, const int parameter,
const int kl, const int ku) {
real result;
// For banded matrices
#if defined(ROUTINE_GBMV)
const int k = ku - y;
if (x >= y-ku && x < y+kl+1) { result = agm[a_ld*y + k + x + a_offset]; }
else { SetToZero(result); }
// For symmetric/hermitian matrices
#elif defined(ROUTINE_HEMV) || defined(ROUTINE_SYMV)
if ((parameter == 0 && y <= x) || (parameter == 1 && x <= y)) {
result = agm[a_ld*y + x + a_offset];
#if defined(ROUTINE_HEMV)
if (x == y) { result.y = ZERO; }
#endif
}
else {
result = agm[a_ld*x + y + a_offset];
#if defined(ROUTINE_HEMV)
COMPLEX_CONJUGATE(result);
#endif
}
// For triangular matrices
#elif defined(ROUTINE_TRMV)
if (((parameter == 0 || parameter == 2) && y <= x) ||
((parameter == 1 || parameter == 3) && x <= y)) {
result = agm[a_ld*y + x + a_offset];
if (parameter >= 2 && y == x) {
SetToOne(result);
}
}
else {
SetToZero(result);
}
// For symmetric/hermitian banded matrices
#elif defined(ROUTINE_HBMV) || defined(ROUTINE_SBMV)
if (parameter == 1) {
if (x <= y) {
const int m = kl - y;
if (x >= y-kl && x <= y) { result = agm[a_ld*y + m + x + a_offset]; }
else { SetToZero(result); }
#if defined(ROUTINE_HBMV)
if (x == y) { result.y = ZERO; }
#endif
}
else {
const int m = kl - x;
if (y >= x-kl && y <= x) { result = agm[a_ld*x + m + y + a_offset]; }
else { SetToZero(result); }
#if defined(ROUTINE_HBMV)
COMPLEX_CONJUGATE(result);
#endif
}
}
else {
if (x >= y) {
const int m = -y;
if (x >= y && x < y+kl+1) { result = agm[a_ld*y + m + x + a_offset]; }
else { SetToZero(result); }
#if defined(ROUTINE_HBMV)
if (x == y) { result.y = ZERO; }
#endif
}
else {
const int m = -x;
if (y >= x && y < x+kl+1) { result = agm[a_ld*x + m + y + a_offset]; }
else { SetToZero(result); }
#if defined(ROUTINE_HBMV)
COMPLEX_CONJUGATE(result);
#endif
}
}
// For triangular banded matrices
#elif defined(ROUTINE_TBMV)
if (parameter == 1 || parameter == 3) {
if (x <= y) {
const int m = kl - y;
if (x >= y-kl && x <= y) { result = agm[a_ld*y + m + x + a_offset]; }
else { SetToZero(result); }
if (parameter >= 2 && y == x) {
SetToOne(result);
}
}
else {
SetToZero(result);
}
}
else {
if (x >= y) {
const int m = -y;
if (x >= y && x < y+kl+1) { result = agm[a_ld*y + m + x + a_offset]; }
else { SetToZero(result); }
if (parameter >= 2 && y == x) {
SetToOne(result);
}
}
else {
SetToZero(result);
}
}
// For symmetric/hermitian packed matrices
#elif defined(ROUTINE_HPMV) || defined(ROUTINE_SPMV)
if (parameter == 1) {
if (x <= y) {
result = agm[((y+1)*y)/2 + x + a_offset];
#if defined(ROUTINE_HPMV)
if (x == y) { result.y = ZERO; }
#endif
}
else {
result = agm[((x+1)*x)/2 + y + a_offset];
#if defined(ROUTINE_HPMV)
COMPLEX_CONJUGATE(result);
#endif
}
}
else {
if (x >= y) {
result = agm[((2*a_ld-(y+1))*y)/2 + x + a_offset];
#if defined(ROUTINE_HPMV)
if (x == y) { result.y = ZERO; }
#endif
}
else {
result = agm[((2*a_ld-(x+1))*x)/2 + y + a_offset];
#if defined(ROUTINE_HPMV)
COMPLEX_CONJUGATE(result);
#endif
}
}
// For triangular packed matrices
#elif defined(ROUTINE_TPMV)
if (parameter == 1 || parameter == 3) {
if (x <= y) {
result = agm[((y+1)*y)/2 + x + a_offset];
if (parameter >= 2 && y == x) {
SetToOne(result);
}
}
else {
SetToZero(result);
}
}
else {
if (x >= y) {
result = agm[((2*a_ld-(y+1))*y)/2 + x + a_offset];
if (parameter >= 2 && y == x) {
SetToOne(result);
}
}
else {
SetToZero(result);
}
}
// For general matrices
#else
result = agm[a_ld*y + x + a_offset];
#endif
return result;
}
// =================================================================================================
// Full version of the kernel
__kernel __attribute__((reqd_work_group_size(WGS1, 1, 1)))
void Xgemv(const int m, const int n,
const real_arg arg_alpha,
const real_arg arg_beta,
const int a_rotated,
const __global real* restrict agm, const int a_offset, const int a_ld,
const __global real* restrict xgm, const int x_offset, const int x_inc,
__global real* ygm, const int y_offset, const int y_inc,
const int do_conjugate, const int parameter,
const int kl, const int ku) {
const real alpha = GetRealArg(arg_alpha);
const real beta = GetRealArg(arg_beta);
// Local memory for the vector X
__local real xlm[WGS1];
// Initializes the accumulation register
#pragma promote_to_registers
real acc1[WPT1];
#pragma unroll
for (int _w = 0; _w < WPT1; _w += 1) {
SetToZero(acc1[_w]);
}
// Divides the work in a main and tail section
const int n_tail = n % WGS1;
const int n_floor = n - n_tail;
// Loops over work-group sized portions of the work
for (int kwg=0; kwg<n_floor; kwg+=WGS1) {
// Loads the vector X into local memory
const int lid = get_local_id(0);
xlm[lid] = xgm[(kwg + lid)*x_inc + x_offset];
// Synchronizes all threads in a workgroup
barrier(CLK_LOCAL_MEM_FENCE);
// Loops over the work per thread, and checks whether in bounds
#pragma unroll
for (int _w = 0; _w < WPT1; _w += 1) {
const int gid = _w*get_global_size(0) + get_global_id(0);
if (gid < m) {
// The multiply-add function for the main part (divisable by WGS1)
if (a_rotated == 0) { // Not rotated
for (int kloop=0; kloop<WGS1; kloop+=UNROLL1) {
#pragma unroll
for (int _kunroll = 0; _kunroll < UNROLL1; _kunroll += 1) {
const int k = kwg + kloop + _kunroll;
real value = LoadMatrixA(agm, gid, k, a_ld, a_offset, parameter, kl, ku);
if (do_conjugate == 1) { COMPLEX_CONJUGATE(value); }
MultiplyAdd(acc1[_w], xlm[kloop + _kunroll], value);
}
}
}
else { // Transposed
for (int kloop=0; kloop<WGS1; kloop+=UNROLL1) {
#pragma unroll
for (int _kunroll = 0; _kunroll < UNROLL1; _kunroll += 1) {
const int k = kwg + kloop + _kunroll;
real value = LoadMatrixA(agm, k, gid, a_ld, a_offset, parameter, kl, ku);
if (do_conjugate == 1) { COMPLEX_CONJUGATE(value); }
MultiplyAdd(acc1[_w], xlm[kloop + _kunroll], value);
}
}
}
}
}
// Synchronizes all threads in a workgroup
barrier(CLK_LOCAL_MEM_FENCE);
}
// Loops over the work per thread, and checks whether in bounds
#pragma unroll
for (int _w = 0; _w < WPT1; _w += 1) {
const int gid = _w*get_global_size(0) + get_global_id(0);
if (gid < m) {
// The multiply-add function for the remainder part (not divisable by WGS1)
if (a_rotated == 0) { // Not rotated
for (int k=n_floor; k<n; ++k) {
real value = LoadMatrixA(agm, gid, k, a_ld, a_offset, parameter, kl, ku);
if (do_conjugate == 1) { COMPLEX_CONJUGATE(value); }
MultiplyAdd(acc1[_w], xgm[k*x_inc + x_offset], value);
}
}
else { // Transposed
for (int k=n_floor; k<n; ++k) {
real value = LoadMatrixA(agm, k, gid, a_ld, a_offset, parameter, kl, ku);
if (do_conjugate == 1) { COMPLEX_CONJUGATE(value); }
MultiplyAdd(acc1[_w], xgm[k*x_inc + x_offset], value);
}
}
// Stores the final result
real yval = ygm[gid*y_inc + y_offset];
AXPBY(ygm[gid*y_inc + y_offset], alpha, acc1[_w], beta, yval);
}
}
}
// =================================================================================================
// End of the C++11 raw string literal
)"
// =================================================================================================
|
