summaryrefslogtreecommitdiff
path: root/tikzit.pro
blob: a8305daa4d037867c44845432d6152532b6ae044 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
# CONFIG += debug

QT += core gui widgets network

VERSION = 2.1.6

test {
    CONFIG += testcase
}

TARGET   = tikzit
TEMPLATE = app

isEmpty(PREFIX) {
    PREFIX=/usr/local
}

share.path = $${PREFIX}/share
share.files = share/*

target.path = $${PREFIX}/bin
INSTALLS += target share

# platform-specific options
win32:RC_ICONS += images/tikzit.ico
win32:RC_ICONS += images/tikzdoc.ico
macx:ICON = images/tikzit.icns
# linux-g++:QMAKE_CXXFLAGS += -Wsuggest-override

QMAKE_INFO_PLIST = Info.plist

# Qt 5.8 and above drop support for Mountain Lion
contains(QT_VERSION, ^5\\.[5-7].*) {
    macx:QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.8
    #macx:QMAKE_MAC_SDK = macosx10.11
}

# The following define makes your compiler emit warnings if you use
# any feature of Qt which as been marked as deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if you use deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

FLEXSOURCES = src/data/tikzlexer.l
BISONSOURCES = src/data/tikzparser.y

include(flex.pri)
include(bison.pri)

SOURCES += src/gui/mainwindow.cpp \
    src/data/path.cpp \
    src/gui/pathitem.cpp \
    src/gui/toolpalette.cpp \
    src/gui/tikzscene.cpp \
    src/data/graph.cpp \
    src/data/node.cpp \
    src/data/edge.cpp \
    src/data/graphelementdata.cpp \
    src/data/graphelementproperty.cpp \
    src/gui/propertypalette.cpp \
    src/gui/tikzview.cpp \
    src/gui/nodeitem.cpp \
    src/gui/edgeitem.cpp \
    src/tikzit.cpp \
    src/gui/commands.cpp \
    src/data/tikzdocument.cpp \
    src/gui/undocommands.cpp \
    src/gui/mainmenu.cpp \
    src/util.cpp \
    src/gui/stylepalette.cpp \
    src/data/tikzassembler.cpp \
    src/data/tikzstyles.cpp \
    src/data/style.cpp \
    src/gui/styleeditor.cpp \
    src/data/stylelist.cpp \
    src/gui/previewwindow.cpp \
    src/gui/latexprocess.cpp \
    src/data/pdfdocument.cpp \
    src/gui/exportdialog.cpp \
    src/data/delimitedstringvalidator.cpp \
    src/gui/delimitedstringitemdelegate.cpp \
    src/gui/preferencedialog.cpp

HEADERS  += src/gui/mainwindow.h \
    src/data/path.h \
    src/gui/pathitem.h \
    src/gui/toolpalette.h \
    src/gui/tikzscene.h \
    src/data/graph.h \
    src/data/node.h \
    src/data/edge.h \
    src/data/graphelementdata.h \
    src/data/graphelementproperty.h \
    src/gui/propertypalette.h \
    src/data/tikzparserdefs.h \
    src/gui/tikzview.h \
    src/gui/nodeitem.h \
    src/tikzit.h \
    src/gui/edgeitem.h \
    src/gui/commands.h \
    src/data/tikzdocument.h \
    src/gui/undocommands.h \
    src/gui/mainmenu.h \
    src/util.h \
    src/gui/stylepalette.h \
    src/data/tikzassembler.h \
    src/data/tikzstyles.h \
    src/data/style.h \
    src/gui/styleeditor.h \
    src/data/stylelist.h \
    src/gui/previewwindow.h \
    src/gui/latexprocess.h \
    src/data/pdfdocument.h \
    src/gui/exportdialog.h \
    src/data/delimitedstringvalidator.h \
    src/gui/delimitedstringitemdelegate.h \
    src/gui/preferencedialog.h

FORMS += src/gui/mainwindow.ui \
    src/gui/propertypalette.ui \
    src/gui/mainmenu.ui \
    src/gui/stylepalette.ui \
    src/gui/styleeditor.ui \
    src/gui/previewwindow.ui \
    src/gui/exportdialog.ui \
    src/gui/preferencedialog.ui

INCLUDEPATH += src src/gui src/data

# link to pre-compiled poppler libs on windows
win32 {
    INCLUDEPATH += win32-deps/include
    LIBS += -L"$$PWD/win32-deps/bin"
}

macx {
    INCLUDEPATH += /usr/local/opt/poppler/include
    LIBS += -L/usr/local/opt/poppler/lib
}   

LIBS += -lpoppler-qt5

DISTFILES +=

RESOURCES += tikzit.qrc

test {
    QT += testlib
    TARGET = UnitTests
    SOURCES -= src/main.cpp
    HEADERS += src/test/testtest.h \
        src/test/testparser.h \
        src/test/testtikzoutput.h
    SOURCES += src/test/testmain.cpp \
        src/test/testtest.cpp \
        src/test/testparser.cpp \
        src/test/testtikzoutput.cpp
} else {
    SOURCES += src/main.cpp
}