1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
|
%option nounput
%option yylineno
%s props
%s xcoord
%s ycoord
%s noderef
FLOAT \-?[0-9]*(\.[0-9]+)?
%{
/*
* Copyright 2010 Chris Heunen
* Copyright 2010-2013 Aleks Kissinger
* Copyright 2013 K. Johan Paulsson
* Copyright 2013 Alex Merry <dev@randomguy3.me.uk>
*
* This program is free software; you can redistribute it and/or
* modify it under the terms of the GNU General Public License as
* published by the Free Software Foundation; either version 2 of
* the License, or (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
#import <Foundation/Foundation.h>
#ifdef __APPLE__
#include "y.tab.h"
#else
#include "tikzparser.h"
#endif
extern char linebuff[500];
extern int lineno;
extern int tokenpos;
%}
%%
%\n /* ignore end of line */;
\n.* { strncpy(linebuff, yytext+1, 500);
linebuff[499] = 0; // ensure null-terminated
lineno++;
tokenpos = 0;
yyless(1);
}
<INITIAL,xcoord,ycoord,props,noderef>[ ]+ { tokenpos += yyleng; } /* ignore whitespace */;
<INITIAL,xcoord,ycoord,props,noderef>[\t]+ { tokenpos += 8*yyleng; } /* ignore whitespace */;
\\begin\{tikzpicture\} { tokenpos += yyleng; return BEGIN_TIKZPICTURE_CMD; }
\\end\{tikzpicture\} { tokenpos += yyleng; return END_TIKZPICTURE_CMD; }
\\begin\{pgfonlayer\} { tokenpos += yyleng; return BEGIN_PGFONLAYER_CMD; }
\\end\{pgfonlayer\} { tokenpos += yyleng; return END_PGFONLAYER_CMD; }
\\draw { tokenpos += yyleng; return DRAW_CMD; }
\\node { tokenpos += yyleng; return NODE_CMD; }
\\path { tokenpos += yyleng; return PATH_CMD; }
rectangle { tokenpos += yyleng; return RECTANGLE; }
node { tokenpos += yyleng; return NODE; }
at { tokenpos += yyleng; return AT; }
to { tokenpos += yyleng; return TO; }
; { tokenpos += yyleng; return SEMICOLON; }
\([ ]*{FLOAT}[ ]*,[ ]*{FLOAT}[ ]*\) {
tokenpos += 1;
yyless(1);
BEGIN(xcoord);
}
<xcoord>{FLOAT} {
tokenpos += yyleng;
yylval.pt.x=(float)strtod(yytext,NULL);
BEGIN(ycoord);
}
<ycoord>, { tokenpos += yyleng; }
<ycoord>{FLOAT} {
tokenpos += yyleng;
yylval.pt.y=(float)strtod(yytext,NULL);
}
<ycoord>\) {
tokenpos += yyleng;
BEGIN(INITIAL);
return COORD;
}
/* when we see "[", change parsing mode */
\[ /*syntaxhlfix]*/ {
tokenpos += yyleng;
BEGIN(props);
return LEFTBRACKET;
}
<props>= { tokenpos += yyleng; return EQUALS; }
<props>, { tokenpos += yyleng; return COMMA; }
<props>[^=,\{\] \t]([^=,\{\]]*[^=,\{\] \t])? {
tokenpos += yyleng;
yylval.nsstr=[NSString stringWithUTF8String:yytext];
return PROPSTRING;
}
<props>\] {
tokenpos += yyleng;
BEGIN(INITIAL);
return RIGHTBRACKET;
}
\( {
tokenpos += yyleng;
BEGIN(noderef);
return LEFTPARENTHESIS;
}
<noderef>\. {
tokenpos += yyleng;
return FULLSTOP;
}
<noderef>[^\.\{\)]+ {
tokenpos += yyleng;
yylval.nsstr=[NSString stringWithUTF8String:yytext];
return REFSTRING;
}
<noderef>\) {
tokenpos += yyleng;
BEGIN(INITIAL);
return RIGHTPARENTHESIS;
}
<INITIAL,props>\{ {
NSMutableString *buf = [NSMutableString string];
unsigned int brace_depth = 1;
unsigned int escape = 0;
while (1) {
char c = input();
// eof reached before closing brace
if (c == '\0' || c == EOF) yyterminate();
if (escape) {
escape = 0;
} else if (c == '\\') {
escape = 1;
} else if (c == '{') {
brace_depth++;
} else if (c == '}') {
brace_depth--;
if (brace_depth == 0) break;
}
[buf appendFormat:@"%c", c];
}
NSString *s = [buf copy];
yyleng += 1 + [buf length];
[s autorelease];
yylval.nsstr = s;
tokenpos += yyleng;
return DELIMITEDSTRING;
}
/* vi:ft=lex:noet:ts=4:sts=4:sw=4:
*/
|
