moved cython functions to subdirectory

3 files changed, 1032 insertions, 0 deletions

diff --git a/pyspike/cython/cython_add.pyx b/pyspike/cython/cython_add.pyx
new file mode 100644
index 0000000..ac64005
--- /dev/null
+++ b/pyspike/cython/cython_add.pyx
@@ -0,0 +1,235 @@
+#cython: boundscheck=False
+#cython: wraparound=False
+#cython: cdivision=True
+
+"""
+cython_add.pyx
+
+cython implementation of the add function for piece-wise const and 
+piece-wise linear functions
+
+Note: using cython memoryviews (e.g. double[:]) instead of ndarray objects
+improves the performance of spike_distance by a factor of 10!
+
+Copyright 2014, Mario Mulansky <mario.mulansky@gmx.net>
+
+Distributed under the BSD License
+
+"""
+
+"""
+To test whether things can be optimized: remove all yellow stuff
+in the html output::
+
+  cython -a cython_add.pyx
+
+which gives::
+
+  cython_add.html
+
+"""
+
+import numpy as np
+cimport numpy as np
+
+from libc.math cimport fabs
+
+DTYPE = np.float
+ctypedef np.float_t DTYPE_t
+
+
+############################################################
+# add_piece_wise_const_cython
+############################################################
+def add_piece_wise_const_cython(double[:] x1, double[:] y1, 
+                                double[:] x2, double[:] y2):
+
+    cdef int N1 = len(x1)
+    cdef int N2 = len(x2)
+    cdef double[:] x_new = np.empty(N1+N2)
+    cdef double[:] y_new = np.empty(N1+N2-1)
+    cdef int index1 = 0
+    cdef int index2 = 0
+    cdef int index = 0
+    cdef int i
+    with nogil: # release the interpreter lock to allow multi-threading
+        x_new[0] = x1[0]
+        y_new[0] = y1[0] + y2[0]
+        while (index1+1 < N1-1) and (index2+1 < N2-1):
+            index += 1
+            # print(index1+1, x1[index1+1], y1[index1+1], x_new[index])
+            if x1[index1+1] < x2[index2+1]:
+                index1 += 1
+                x_new[index] = x1[index1]
+            elif x1[index1+1] > x2[index2+1]:
+                index2 += 1
+                x_new[index] = x2[index2]
+            else: # x1[index1+1] == x2[index2+1]:
+                index1 += 1
+                index2 += 1
+                x_new[index] = x1[index1]
+            y_new[index] = y1[index1] + y2[index2]
+        # one array reached the end -> copy the contents of the other to the end
+        if index1+1 < N1-1:
+            x_new[index+1:index+1+N1-index1-1] = x1[index1+1:]
+            for i in xrange(N1-index1-2):
+                y_new[index+1+i] = y1[index1+1+i] + y2[N2-2]
+            index += N1-index1-2
+        elif index2+1 < N2-1:
+            x_new[index+1:index+1+N2-index2-1] = x2[index2+1:]
+            for i in xrange(N2-index2-2):
+                y_new[index+1+i] = y2[index2+1+i] + y1[N1-2]
+            index += N2-index2-2
+        else: # both arrays reached the end simultaneously
+            # only the last x-value missing
+            x_new[index+1] = x1[N1-1]
+        # the last value is again the end of the interval
+        # x_new[index+1] = x1[-1]
+        # only use the data that was actually filled
+        x1 = x_new[:index+2]
+        y1 = y_new[:index+1]
+    # end nogil
+    return np.array(x_new[:index+2]), np.array(y_new[:index+1])
+
+
+############################################################
+# add_piece_wise_lin_cython
+############################################################
+def add_piece_wise_lin_cython(double[:] x1, double[:] y11, double[:] y12, 
+                              double[:] x2, double[:] y21, double[:] y22):
+    cdef int N1 = len(x1)
+    cdef int N2 = len(x2)
+    cdef double[:] x_new = np.empty(N1+N2)
+    cdef double[:] y1_new = np.empty(N1+N2-1)
+    cdef double[:] y2_new = np.empty_like(y1_new)
+    cdef int index1 = 0 # index for self
+    cdef int index2 = 0 # index for f
+    cdef int index = 0  # index for new
+    cdef int i
+    cdef double y
+    with nogil: # release the interpreter lock to allow multi-threading
+        x_new[0] = x1[0]
+        y1_new[0] = y11[0] + y21[0]
+        while (index1+1 < N1-1) and (index2+1 < N2-1):
+            # print(index1+1, x1[index1+1], self.y[index1+1], x_new[index])
+            if x1[index1+1] < x2[index2+1]:
+                # first compute the end value of the previous interval
+                # linear interpolation of the interval
+                y = y21[index2] + (y22[index2]-y21[index2]) * \
+                    (x1[index1+1]-x2[index2]) / (x2[index2+1]-x2[index2])
+                y2_new[index] = y12[index1] + y
+                index1 += 1
+                index += 1
+                x_new[index] = x1[index1]
+                # and the starting value for the next interval
+                y1_new[index] = y11[index1] + y
+            elif x1[index1+1] > x2[index2+1]:
+                # first compute the end value of the previous interval
+                # linear interpolation of the interval
+                y = y11[index1] + (y12[index1]-y11[index1]) * \
+                    (x2[index2+1]-x1[index1]) / \
+                    (x1[index1+1]-x1[index1])
+                y2_new[index] = y22[index2] + y
+                index2 += 1
+                index += 1
+                x_new[index] = x2[index2]
+                # and the starting value for the next interval
+                y1_new[index] = y21[index2] + y
+            else: # x1[index1+1] == x2[index2+1]:
+                y2_new[index] = y12[index1] + y22[index2]
+                index1 += 1
+                index2 += 1
+                index += 1
+                x_new[index] = x1[index1]
+                y1_new[index] = y11[index1] + y21[index2]
+        # one array reached the end -> copy the contents of the other to the end
+        if index1+1 < N1-1:
+            x_new[index+1:index+1+N1-index1-1] = x1[index1+1:]
+            for i in xrange(N1-index1-2):
+                # compute the linear interpolations value
+                y = y21[index2] + (y22[index2]-y21[index2]) * \
+                    (x1[index1+1+i]-x2[index2]) / (x2[index2+1]-x2[index2])
+                y1_new[index+1+i] = y11[index1+1+i] + y
+                y2_new[index+i] = y12[index1+i] + y
+            index += N1-index1-2
+        elif index2+1 < N2-1:
+            x_new[index+1:index+1+N2-index2-1] = x2[index2+1:]
+            # compute the linear interpolations values
+            for i in xrange(N2-index2-2):
+                y = y11[index1] + (y12[index1]-y11[index1]) * \
+                    (x2[index2+1+i]-x1[index1]) / \
+                    (x1[index1+1]-x1[index1])
+                y1_new[index+1+i] = y21[index2+1+i] + y
+                y2_new[index+i] = y22[index2+i] + y
+            index += N2-index2-2
+        else: # both arrays reached the end simultaneously
+            # only the last x-value missing
+            x_new[index+1] = x1[N1-1]
+        # finally, the end value for the last interval
+        y2_new[index] = y12[N1-2]+y22[N2-2]
+        # only use the data that was actually filled
+    # end nogil
+    return (np.array(x_new[:index+2]),
+            np.array(y1_new[:index+1]), 
+            np.array(y2_new[:index+1]))
+
+
+############################################################
+# add_discrete_function_cython
+############################################################
+def add_discrete_function_cython(double[:] x1, double[:] y1, double[:] mp1,
+                                 double[:] x2, double[:] y2, double[:] mp2):
+
+    cdef double[:] x_new = np.empty(len(x1) + len(x2))
+    cdef double[:] y_new = np.empty_like(x_new)
+    cdef double[:] mp_new = np.empty_like(x_new)
+    cdef int index1 = 0
+    cdef int index2 = 0
+    cdef int index = 0
+    cdef int N1 = len(y1)
+    cdef int N2 = len(y2)
+    x_new[0] = x1[0]
+    while (index1+1 < N1) and (index2+1 < N2):
+        if x1[index1+1] < x2[index2+1]:
+            index1 += 1
+            index += 1
+            x_new[index] = x1[index1]
+            y_new[index] = y1[index1]
+            mp_new[index] = mp1[index1]
+        elif x1[index1+1] > x2[index2+1]:
+            index2 += 1
+            index += 1
+            x_new[index] = x2[index2]
+            y_new[index] = y2[index2]
+            mp_new[index] = mp2[index2]
+        else:  # x1[index1+1] == x2[index2+1]
+            index1 += 1
+            index2 += 1
+            index += 1
+            x_new[index] = x1[index1]
+            y_new[index] = y1[index1] + y2[index2]
+            mp_new[index] = mp1[index1] + mp2[index2]
+    # one array reached the end -> copy the contents of the other to the end
+    if index1+1 < len(y1):
+        x_new[index+1:index+1+len(x1)-index1-1] = x1[index1+1:]
+        y_new[index+1:index+1+len(x1)-index1-1] = y1[index1+1:]
+        mp_new[index+1:index+1+len(x1)-index1-1] = mp1[index1+1:]
+        index += len(x1)-index1-1
+    elif index2+1 < len(y2):
+        x_new[index+1:index+1+len(x2)-index2-1] = x2[index2+1:]
+        y_new[index+1:index+1+len(x2)-index2-1] = y2[index2+1:]
+        mp_new[index+1:index+1+len(x2)-index2-1] = mp2[index2+1:]
+        index += len(x2)-index2-1
+    # else:  # both arrays reached the end simultaneously
+    #     x_new[index+1] = x1[-1]
+    #     y_new[index+1] = y1[-1] + y2[-1]
+    #     mp_new[index+1] = mp1[-1] + mp2[-1]
+
+    y_new[0] = y_new[1]
+    mp_new[0] = mp_new[1]
+
+    # the last value is again the end of the interval
+    # only use the data that was actually filled
+    return (np.array(x_new[:index+1]), 
+            np.array(y_new[:index+1]), 
+            np.array(mp_new[:index+1]))
diff --git a/pyspike/cython/cython_distance.pyx b/pyspike/cython/cython_distance.pyx
new file mode 100644
index 0000000..489aab9
--- /dev/null
+++ b/pyspike/cython/cython_distance.pyx
@@ -0,0 +1,312 @@
+#cython: boundscheck=False
+#cython: wraparound=False
+#cython: cdivision=True
+
+"""
+cython_distances.pyx
+
+cython implementation of the isi- and spike-distance
+
+Note: using cython memoryviews (e.g. double[:]) instead of ndarray objects
+improves the performance of spike_distance by a factor of 10!
+
+Copyright 2014, Mario Mulansky <mario.mulansky@gmx.net>
+
+Distributed under the BSD License
+
+"""
+
+"""
+To test whether things can be optimized: remove all yellow stuff
+in the html output::
+
+  cython -a cython_distance.pyx
+
+which gives::
+
+  cython_distance.html
+
+"""
+
+import numpy as np
+cimport numpy as np
+
+from libc.math cimport fabs
+from libc.math cimport fmax
+from libc.math cimport fmin
+
+DTYPE = np.float
+ctypedef np.float_t DTYPE_t
+
+
+############################################################
+# isi_distance_cython
+############################################################
+def isi_distance_cython(double[:] s1, 
+                        double[:] s2):
+
+    cdef double[:] spike_events
+    cdef double[:] isi_values
+    cdef int index1, index2, index
+    cdef int N1, N2
+    cdef double nu1, nu2
+    N1 = len(s1)-1
+    N2 = len(s2)-1
+
+    nu1 = s1[1]-s1[0]
+    nu2 = s2[1]-s2[0]
+    spike_events = np.empty(N1+N2)
+    spike_events[0] = s1[0]
+    # the values have one entry less - the number of intervals between events
+    isi_values = np.empty(N1+N2-1)
+
+    with nogil: # release the interpreter to allow multithreading
+        isi_values[0] = fabs(nu1-nu2)/fmax(nu1, nu2)
+        index1 = 0
+        index2 = 0
+        index = 1
+        while True:
+            # check which spike is next - from s1 or s2
+            if s1[index1+1] < s2[index2+1]:
+                index1 += 1
+                # break condition relies on existence of spikes at T_end
+                if index1 >= N1:
+                    break
+                spike_events[index] = s1[index1]
+                nu1 = s1[index1+1]-s1[index1]
+            elif s1[index1+1] > s2[index2+1]:
+                index2 += 1
+                if index2 >= N2:
+                    break
+                spike_events[index] = s2[index2]
+                nu2 = s2[index2+1]-s2[index2]
+            else: # s1[index1+1] == s2[index2+1]
+                index1 += 1
+                index2 += 1
+                if (index1 >= N1) or (index2 >= N2):
+                    break
+                spike_events[index] = s1[index1]
+                nu1 = s1[index1+1]-s1[index1]
+                nu2 = s2[index2+1]-s2[index2]            
+            # compute the corresponding isi-distance
+            isi_values[index] = fabs(nu1 - nu2) / fmax(nu1, nu2)
+            index += 1
+        # the last event is the interval end
+        spike_events[index] = s1[N1]
+    # end nogil
+
+    return spike_events[:index+1], isi_values[:index]
+
+
+############################################################
+# get_min_dist_cython
+############################################################
+cdef inline double get_min_dist_cython(double spike_time, 
+                                       double[:] spike_train,
+                                       # use memory view to ensure inlining
+                                       # np.ndarray[DTYPE_t,ndim=1] spike_train,
+                                       int N,
+                                       int start_index=0) nogil:
+    """ Returns the minimal distance |spike_time - spike_train[i]| 
+    with i>=start_index.
+    """
+    cdef double d, d_temp
+    d = fabs(spike_time - spike_train[start_index])
+    start_index += 1
+    while start_index < N:
+        d_temp = fabs(spike_time - spike_train[start_index])
+        if d_temp > d:
+            break
+        else:
+            d = d_temp
+        start_index += 1
+    return d
+
+
+############################################################
+# isi_avrg_cython
+############################################################
+cdef inline double isi_avrg_cython(double isi1, double isi2) nogil:
+    return 0.5*(isi1+isi2)*(isi1+isi2)
+    # alternative definition to obtain <S> ~ 0.5 for Poisson spikes
+    # return 0.5*(isi1*isi1+isi2*isi2)
+
+
+############################################################
+# spike_distance_cython
+############################################################
+def spike_distance_cython(double[:] t1, 
+                          double[:] t2):
+
+    cdef double[:] spike_events
+    cdef double[:] y_starts
+    cdef double[:] y_ends
+
+    cdef int N1, N2, index1, index2, index
+    cdef double dt_p1, dt_p2, dt_f1, dt_f2, isi1, isi2, s1, s2
+
+    N1 = len(t1)
+    N2 = len(t2)
+
+    spike_events = np.empty(N1+N2-2)
+    spike_events[0] = t1[0]
+    y_starts = np.empty(len(spike_events)-1)
+    y_ends = np.empty(len(spike_events)-1)
+
+    with nogil: # release the interpreter to allow multithreading
+        index1 = 0
+        index2 = 0
+        index = 1
+        dt_p1 = 0.0
+        dt_f1 = get_min_dist_cython(t1[1], t2, N2, 0)
+        dt_p2 = 0.0
+        dt_f2 = get_min_dist_cython(t2[1], t1, N1, 0)
+        isi1 = max(t1[1]-t1[0], t1[2]-t1[1])
+        isi2 = max(t2[1]-t2[0], t2[2]-t2[1])
+        s1 = dt_f1*(t1[1]-t1[0])/isi1
+        s2 = dt_f2*(t2[1]-t2[0])/isi2
+        y_starts[0] = (s1*isi2 + s2*isi1) / isi_avrg_cython(isi1, isi2)
+        while True:
+            # print(index, index1, index2)
+            if t1[index1+1] < t2[index2+1]:
+                index1 += 1
+                # break condition relies on existence of spikes at T_end
+                if index1+1 >= N1:
+                    break
+                spike_events[index] = t1[index1]
+                # first calculate the previous interval end value
+                dt_p1 = dt_f1 # the previous time now was the following time before
+                s1 = dt_p1
+                s2 = (dt_p2*(t2[index2+1]-t1[index1]) + 
+                      dt_f2*(t1[index1]-t2[index2])) / isi2
+                y_ends[index-1] = (s1*isi2 + s2*isi1)/isi_avrg_cython(isi1, isi2)
+                # now the next interval start value
+                dt_f1 = get_min_dist_cython(t1[index1+1], t2, N2, index2)
+                isi1 = t1[index1+1]-t1[index1]
+                # s2 is the same as above, thus we can compute y2 immediately
+                y_starts[index] = (s1*isi2 + s2*isi1)/isi_avrg_cython(isi1, isi2)
+            elif t1[index1+1] > t2[index2+1]:
+                index2 += 1
+                if index2+1 >= N2:
+                    break
+                spike_events[index] = t2[index2]
+                # first calculate the previous interval end value
+                dt_p2 = dt_f2 # the previous time now was the following time before
+                s1 = (dt_p1*(t1[index1+1]-t2[index2]) + 
+                      dt_f1*(t2[index2]-t1[index1])) / isi1
+                s2 = dt_p2
+                y_ends[index-1] = (s1*isi2 + s2*isi1) / isi_avrg_cython(isi1, isi2)
+                # now the next interval start value
+                dt_f2 = get_min_dist_cython(t2[index2+1], t1, N1, index1)
+                #s2 = dt_f2
+                isi2 = t2[index2+1]-t2[index2]
+                # s2 is the same as above, thus we can compute y2 immediately
+                y_starts[index] = (s1*isi2 + s2*isi1)/isi_avrg_cython(isi1, isi2)
+            else: # t1[index1+1] == t2[index2+1] - generate only one event
+                index1 += 1
+                index2 += 1
+                if (index1+1 >= N1) or (index2+1 >= N2):
+                    break
+                spike_events[index] = t1[index1]
+                y_ends[index-1] = 0.0
+                y_starts[index] = 0.0
+                dt_p1 = 0.0
+                dt_p2 = 0.0
+                dt_f1 = get_min_dist_cython(t1[index1+1], t2, N2, index2)
+                dt_f2 = get_min_dist_cython(t2[index2+1], t1, N1, index1)
+                isi1 = t1[index1+1]-t1[index1]
+                isi2 = t2[index2+1]-t2[index2]
+            index += 1
+        # the last event is the interval end
+        spike_events[index] = t1[N1-1]
+        # the ending value of the last interval
+        isi1 = max(t1[N1-1]-t1[N1-2], t1[N1-2]-t1[N1-3])
+        isi2 = max(t2[N2-1]-t2[N2-2], t2[N2-2]-t2[N2-3])
+        s1 = dt_p1*(t1[N1-1]-t1[N1-2])/isi1
+        s2 = dt_p2*(t2[N2-1]-t2[N2-2])/isi2
+        y_ends[index-1] = (s1*isi2 + s2*isi1) / isi_avrg_cython(isi1, isi2)
+    # end nogil
+
+    # use only the data added above 
+    # could be less than original length due to equal spike times
+    return spike_events[:index+1], y_starts[:index], y_ends[:index]
+
+
+
+############################################################
+# coincidence_python
+############################################################
+cdef inline double get_tau(double[:] spikes1, double[:] spikes2, int i, int j):
+    cdef double m = 1E100   # some huge number
+    cdef int N1 = len(spikes1)-2
+    cdef int N2 = len(spikes2)-2
+    if i < N1:
+        m = fmin(m, spikes1[i+1]-spikes1[i])
+    if j < N2:
+        m = fmin(m, spikes2[j+1]-spikes2[j])
+    if i > 1:
+        m = fmin(m, spikes1[i]-spikes1[i-1])
+    if j > 1:
+        m = fmin(m, spikes2[j]-spikes2[j-1])
+    return 0.5*m
+    
+
+############################################################
+# coincidence_cython
+############################################################
+def coincidence_cython(double[:] spikes1, double[:] spikes2):
+
+    cdef int N1 = len(spikes1)
+    cdef int N2 = len(spikes2)
+    cdef int i = 0
+    cdef int j = 0
+    cdef int n = 0
+    cdef double[:] st = np.zeros(N1 + N2 - 2)  # spike times
+    cdef double[:] c = np.zeros(N1 + N2 - 2)   # coincidences
+    cdef double[:] mp = np.ones(N1 + N2 - 2)   # multiplicity
+    cdef double tau
+    while n < N1 + N2 - 2:
+        if spikes1[i+1] < spikes2[j+1]:
+            i += 1
+            n += 1
+            tau = get_tau(spikes1, spikes2, i, j)
+            st[n] = spikes1[i]
+            if j > 0 and spikes1[i]-spikes2[j] < tau:
+                # coincidence between the current spike and the previous spike
+                # both get marked with 1
+                c[n] = 1
+                c[n-1] = 1
+        elif spikes1[i+1] > spikes2[j+1]:
+            j += 1
+            n += 1
+            tau = get_tau(spikes1, spikes2, i, j)
+            st[n] = spikes2[j]
+            if i > 0 and spikes2[j]-spikes1[i] < tau:
+                # coincidence between the current spike and the previous spike
+                # both get marked with 1
+                c[n] = 1
+                c[n-1] = 1
+        else:   # spikes1[i+1] = spikes2[j+1]
+            # advance in both spike trains
+            j += 1
+            i += 1
+            if i == N1-1 or j == N2-1:
+                break
+            n += 1
+            # add only one event, but with coincidence 2 and multiplicity 2
+            st[n] = spikes1[i]
+            c[n] = 2
+            mp[n] = 2
+
+    st = st[:n+2]
+    c = c[:n+2]
+    mp = mp[:n+2]
+
+    st[0] = spikes1[0]
+    st[len(st)-1] = spikes1[len(spikes1)-1]
+    c[0] = c[1]
+    c[len(c)-1] = c[len(c)-2]
+    mp[0] = mp[1]
+    mp[len(mp)-1] = mp[len(mp)-2]
+
+    return st, c, mp
diff --git a/pyspike/cython/python_backend.py b/pyspike/cython/python_backend.py
new file mode 100644
index 0000000..481daf9
--- /dev/null
+++ b/pyspike/cython/python_backend.py
@@ -0,0 +1,485 @@
+""" python_backend.py
+
+Collection of python functions that can be used instead of the cython
+implementation.
+
+Copyright 2014, Mario Mulansky <mario.mulansky@gmx.net>
+
+Distributed under the BSD License
+
+"""
+
+import numpy as np
+
+
+############################################################
+# isi_distance_python
+############################################################
+def isi_distance_python(s1, s2):
+    """ Plain Python implementation of the isi distance.
+    """
+    # compute the interspike interval
+    nu1 = s1[1:] - s1[:-1]
+    nu2 = s2[1:] - s2[:-1]
+
+    # compute the isi-distance
+    spike_events = np.empty(len(nu1) + len(nu2))
+    spike_events[0] = s1[0]
+    # the values have one entry less - the number of intervals between events
+    isi_values = np.empty(len(spike_events) - 1)
+    # add the distance of the first events
+    # isi_values[0] = nu1[0]/nu2[0] - 1.0 if nu1[0] <= nu2[0] \
+    #                 else 1.0 - nu2[0]/nu1[0]
+    isi_values[0] = abs(nu1[0] - nu2[0]) / max(nu1[0], nu2[0])
+    index1 = 0
+    index2 = 0
+    index = 1
+    while True:
+        # check which spike is next - from s1 or s2
+        if s1[index1+1] < s2[index2+1]:
+            index1 += 1
+            # break condition relies on existence of spikes at T_end
+            if index1 >= len(nu1):
+                break
+            spike_events[index] = s1[index1]
+        elif s1[index1+1] > s2[index2+1]:
+            index2 += 1
+            if index2 >= len(nu2):
+                break
+            spike_events[index] = s2[index2]
+        else:  # s1[index1 + 1] == s2[index2 + 1]
+            index1 += 1
+            index2 += 1
+            if (index1 >= len(nu1)) or (index2 >= len(nu2)):
+                break
+            spike_events[index] = s1[index1]
+        # compute the corresponding isi-distance
+        isi_values[index] = abs(nu1[index1] - nu2[index2]) / \
+            max(nu1[index1], nu2[index2])
+        index += 1
+    # the last event is the interval end
+    spike_events[index] = s1[-1]
+    # use only the data added above
+    # could be less than original length due to equal spike times
+    return spike_events[:index + 1], isi_values[:index]
+
+
+############################################################
+# get_min_dist
+############################################################
+def get_min_dist(spike_time, spike_train, start_index=0):
+    """ Returns the minimal distance |spike_time - spike_train[i]|
+    with i>=start_index.
+    """
+    d = abs(spike_time - spike_train[start_index])
+    start_index += 1
+    while start_index < len(spike_train):
+        d_temp = abs(spike_time - spike_train[start_index])
+        if d_temp > d:
+            break
+        else:
+            d = d_temp
+        start_index += 1
+    return d
+
+
+############################################################
+# spike_distance_python
+############################################################
+def spike_distance_python(spikes1, spikes2):
+    """ Computes the instantaneous spike-distance S_spike (t) of the two given
+    spike trains. The spike trains are expected to have auxiliary spikes at the
+    beginning and end of the interval. Use the function add_auxiliary_spikes to
+    add those spikes to the spike train.
+    Args:
+    - spikes1, spikes2: ordered arrays of spike times with auxiliary spikes.
+    Returns:
+    - PieceWiseLinFunc describing the spike-distance.
+    """
+    # check for auxiliary spikes - first and last spikes should be identical
+    assert spikes1[0] == spikes2[0], \
+        "Given spike trains seems not to have auxiliary spikes!"
+    assert spikes1[-1] == spikes2[-1], \
+        "Given spike trains seems not to have auxiliary spikes!"
+    # shorter variables
+    t1 = spikes1
+    t2 = spikes2
+
+    spike_events = np.empty(len(t1) + len(t2) - 2)
+    spike_events[0] = t1[0]
+    y_starts = np.empty(len(spike_events) - 1)
+    y_ends = np.empty(len(spike_events) - 1)
+
+    index1 = 0
+    index2 = 0
+    index = 1
+    dt_p1 = 0.0
+    dt_f1 = get_min_dist(t1[1], t2, 0)
+    dt_p2 = 0.0
+    dt_f2 = get_min_dist(t2[1], t1, 0)
+    isi1 = max(t1[1]-t1[0], t1[2]-t1[1])
+    isi2 = max(t2[1]-t2[0], t2[2]-t2[1])
+    s1 = dt_f1*(t1[1]-t1[0])/isi1
+    s2 = dt_f2*(t2[1]-t2[0])/isi2
+    y_starts[0] = (s1*isi2 + s2*isi1) / ((isi1+isi2)**2/2)
+    while True:
+        # print(index, index1, index2)
+        if t1[index1+1] < t2[index2+1]:
+            index1 += 1
+            # break condition relies on existence of spikes at T_end
+            if index1+1 >= len(t1):
+                break
+            spike_events[index] = t1[index1]
+            # first calculate the previous interval end value
+            dt_p1 = dt_f1  # the previous time was the following time before
+            s1 = dt_p1
+            s2 = (dt_p2*(t2[index2+1]-t1[index1]) +
+                  dt_f2*(t1[index1]-t2[index2])) / isi2
+            y_ends[index-1] = (s1*isi2 + s2*isi1) / ((isi1+isi2)**2/2)
+            # now the next interval start value
+            dt_f1 = get_min_dist(t1[index1+1], t2, index2)
+            isi1 = t1[index1+1]-t1[index1]
+            # s2 is the same as above, thus we can compute y2 immediately
+            y_starts[index] = (s1*isi2 + s2*isi1) / ((isi1+isi2)**2/2)
+        elif t1[index1+1] > t2[index2+1]:
+            index2 += 1
+            if index2+1 >= len(t2):
+                break
+            spike_events[index] = t2[index2]
+            # first calculate the previous interval end value
+            dt_p2 = dt_f2  # the previous time was the following time before
+            s1 = (dt_p1*(t1[index1+1]-t2[index2]) +
+                  dt_f1*(t2[index2]-t1[index1])) / isi1
+            s2 = dt_p2
+            y_ends[index-1] = (s1*isi2 + s2*isi1) / ((isi1+isi2)**2/2)
+            # now the next interval start value
+            dt_f2 = get_min_dist(t2[index2+1], t1, index1)
+            #s2 = dt_f2
+            isi2 = t2[index2+1]-t2[index2]
+            # s2 is the same as above, thus we can compute y2 immediately
+            y_starts[index] = (s1*isi2 + s2*isi1) / ((isi1+isi2)**2/2)
+        else:  # t1[index1+1] == t2[index2+1] - generate only one event
+            index1 += 1
+            index2 += 1
+            if (index1+1 >= len(t1)) or (index2+1 >= len(t2)):
+                break
+            assert dt_f2 == 0.0
+            assert dt_f1 == 0.0
+            spike_events[index] = t1[index1]
+            y_ends[index-1] = 0.0
+            y_starts[index] = 0.0
+            dt_p1 = 0.0
+            dt_p2 = 0.0
+            dt_f1 = get_min_dist(t1[index1+1], t2, index2)
+            dt_f2 = get_min_dist(t2[index2+1], t1, index1)
+            isi1 = t1[index1+1]-t1[index1]
+            isi2 = t2[index2+1]-t2[index2]
+        index += 1
+    # the last event is the interval end
+    spike_events[index] = t1[-1]
+    # the ending value of the last interval
+    isi1 = max(t1[-1]-t1[-2], t1[-2]-t1[-3])
+    isi2 = max(t2[-1]-t2[-2], t2[-2]-t2[-3])
+    s1 = dt_p1*(t1[-1]-t1[-2])/isi1
+    s2 = dt_p2*(t2[-1]-t2[-2])/isi2
+    y_ends[index-1] = (s1*isi2 + s2*isi1) / ((isi1+isi2)**2/2)
+    # use only the data added above
+    # could be less than original length due to equal spike times
+    return spike_events[:index+1], y_starts[:index], y_ends[:index]
+
+
+############################################################
+# cumulative_sync_python
+############################################################
+def cumulative_sync_python(spikes1, spikes2):
+
+    def get_tau(spikes1, spikes2, i, j):
+        return 0.5*min([spikes1[i]-spikes1[i-1], spikes1[i+1]-spikes1[i],
+                        spikes2[j]-spikes2[j-1], spikes2[j+1]-spikes2[j]])
+    N1 = len(spikes1)
+    N2 = len(spikes2)
+    i = 0
+    j = 0
+    n = 0
+    st = np.zeros(N1 + N2 - 2)
+    c = np.zeros(N1 + N2 - 3)
+    c[0] = 0
+    st[0] = 0
+    while n < N1 + N2:
+        if spikes1[i+1] < spikes2[j+1]:
+            i += 1
+            n += 1
+            tau = get_tau(spikes1, spikes2, i, j)
+            st[n] = spikes1[i]
+            if spikes1[i]-spikes2[j] > tau:
+                c[n] = c[n-1]
+            else:
+                c[n] = c[n-1]+1
+        elif spikes1[i+1] > spikes2[j+1]:
+            j += 1
+            n += 1
+            tau = get_tau(spikes1, spikes2, i, j)
+            st[n] = spikes2[j]
+            if spikes2[j]-spikes1[i] > tau:
+                c[n] = c[n-1]
+            else:
+                c[n] = c[n-1]+1
+        else:   # spikes1[i+1] = spikes2[j+1]
+            j += 1
+            i += 1
+            if i == N1-1 or j == N2-1:
+                break
+            n += 1
+            st[n] = spikes1[i]
+            c[n] = c[n-1]
+            n += 1
+            st[n] = spikes1[i]
+            c[n] = c[n-1]+1
+    c[0] = 0
+    st[0] = spikes1[0]
+    st[-1] = spikes1[-1]
+
+    return st, c
+
+
+############################################################
+# coincidence_python
+############################################################
+def coincidence_python(spikes1, spikes2):
+
+    def get_tau(spikes1, spikes2, i, j):
+        m = 1E100   # some huge number
+        if i < len(spikes1)-2:
+            m = min(m, spikes1[i+1]-spikes1[i])
+        if j < len(spikes2)-2:
+            m = min(m, spikes2[j+1]-spikes2[j])
+        if i > 1:
+            m = min(m, spikes1[i]-spikes1[i-1])
+        if j > 1:
+            m = min(m, spikes2[j]-spikes2[j-1])
+        return 0.5*m
+    N1 = len(spikes1)
+    N2 = len(spikes2)
+    i = 0
+    j = 0
+    n = 0
+    st = np.zeros(N1 + N2 - 2)  # spike times
+    c = np.zeros(N1 + N2 - 2)   # coincidences
+    mp = np.ones(N1 + N2 - 2)   # multiplicity
+    while n < N1 + N2 - 2:
+        if spikes1[i+1] < spikes2[j+1]:
+            i += 1
+            n += 1
+            tau = get_tau(spikes1, spikes2, i, j)
+            st[n] = spikes1[i]
+            if j > 0 and spikes1[i]-spikes2[j] < tau:
+                # coincidence between the current spike and the previous spike
+                # both get marked with 1
+                c[n] = 1
+                c[n-1] = 1
+        elif spikes1[i+1] > spikes2[j+1]:
+            j += 1
+            n += 1
+            tau = get_tau(spikes1, spikes2, i, j)
+            st[n] = spikes2[j]
+            if i > 0 and spikes2[j]-spikes1[i] < tau:
+                # coincidence between the current spike and the previous spike
+                # both get marked with 1
+                c[n] = 1
+                c[n-1] = 1
+        else:   # spikes1[i+1] = spikes2[j+1]
+            # advance in both spike trains
+            j += 1
+            i += 1
+            if i == N1-1 or j == N2-1:
+                break
+            n += 1
+            # add only one event, but with coincidence 2 and multiplicity 2
+            st[n] = spikes1[i]
+            c[n] = 2
+            mp[n] = 2
+
+    st = st[:n+2]
+    c = c[:n+2]
+    mp = mp[:n+2]
+
+    st[0] = spikes1[0]
+    st[-1] = spikes1[-1]
+    c[0] = c[1]
+    c[-1] = c[-2]
+    mp[0] = mp[1]
+    mp[-1] = mp[-2]
+
+    return st, c, mp
+
+
+############################################################
+# add_piece_wise_const_python
+############################################################
+def add_piece_wise_const_python(x1, y1, x2, y2):
+    x_new = np.empty(len(x1) + len(x2))
+    y_new = np.empty(len(x_new)-1)
+    x_new[0] = x1[0]
+    y_new[0] = y1[0] + y2[0]
+    index1 = 0
+    index2 = 0
+    index = 0
+    while (index1+1 < len(y1)) and (index2+1 < len(y2)):
+        index += 1
+        # print(index1+1, x1[index1+1], y1[index1+1], x_new[index])
+        if x1[index1+1] < x2[index2+1]:
+            index1 += 1
+            x_new[index] = x1[index1]
+        elif x1[index1+1] > x2[index2+1]:
+            index2 += 1
+            x_new[index] = x2[index2]
+        else:  # x1[index1+1] == x2[index2+1]:
+            index1 += 1
+            index2 += 1
+            x_new[index] = x1[index1]
+        y_new[index] = y1[index1] + y2[index2]
+    # one array reached the end -> copy the contents of the other to the end
+    if index1+1 < len(y1):
+        x_new[index+1:index+1+len(x1)-index1-1] = x1[index1+1:]
+        y_new[index+1:index+1+len(y1)-index1-1] = y1[index1+1:] + y2[-1]
+        index += len(x1)-index1-2
+    elif index2+1 < len(y2):
+        x_new[index+1:index+1+len(x2)-index2-1] = x2[index2+1:]
+        y_new[index+1:index+1+len(y2)-index2-1] = y2[index2+1:] + y1[-1]
+        index += len(x2)-index2-2
+    else:  # both arrays reached the end simultaneously
+        # only the last x-value missing
+        x_new[index+1] = x1[-1]
+    # the last value is again the end of the interval
+    # x_new[index+1] = x1[-1]
+    # only use the data that was actually filled
+
+    return x_new[:index+2], y_new[:index+1]
+
+
+############################################################
+# add_piece_lin_const_python
+############################################################
+def add_piece_wise_lin_python(x1, y11, y12, x2, y21, y22):
+    x_new = np.empty(len(x1) + len(x2))
+    y1_new = np.empty(len(x_new)-1)
+    y2_new = np.empty_like(y1_new)
+    x_new[0] = x1[0]
+    y1_new[0] = y11[0] + y21[0]
+    index1 = 0  # index for self
+    index2 = 0  # index for f
+    index = 0   # index for new
+    while (index1+1 < len(y11)) and (index2+1 < len(y21)):
+        # print(index1+1, x1[index1+1], self.y[index1+1], x_new[index])
+        if x1[index1+1] < x2[index2+1]:
+            # first compute the end value of the previous interval
+            # linear interpolation of the interval
+            y = y21[index2] + (y22[index2]-y21[index2]) * \
+                (x1[index1+1]-x2[index2]) / (x2[index2+1]-x2[index2])
+            y2_new[index] = y12[index1] + y
+            index1 += 1
+            index += 1
+            x_new[index] = x1[index1]
+            # and the starting value for the next interval
+            y1_new[index] = y11[index1] + y
+        elif x1[index1+1] > x2[index2+1]:
+            # first compute the end value of the previous interval
+            # linear interpolation of the interval
+            y = y11[index1] + (y12[index1]-y11[index1]) * \
+                (x2[index2+1]-x1[index1]) / \
+                (x1[index1+1]-x1[index1])
+            y2_new[index] = y22[index2] + y
+            index2 += 1
+            index += 1
+            x_new[index] = x2[index2]
+            # and the starting value for the next interval
+            y1_new[index] = y21[index2] + y
+        else:  # x1[index1+1] == x2[index2+1]:
+            y2_new[index] = y12[index1] + y22[index2]
+            index1 += 1
+            index2 += 1
+            index += 1
+            x_new[index] = x1[index1]
+            y1_new[index] = y11[index1] + y21[index2]
+    # one array reached the end -> copy the contents of the other to the end
+    if index1+1 < len(y11):
+        # compute the linear interpolations values
+        y = y21[index2] + (y22[index2]-y21[index2]) * \
+            (x1[index1+1:-1]-x2[index2]) / (x2[index2+1]-x2[index2])
+        x_new[index+1:index+1+len(x1)-index1-1] = x1[index1+1:]
+        y1_new[index+1:index+1+len(y11)-index1-1] = y11[index1+1:]+y
+        y2_new[index:index+len(y12)-index1-1] = y12[index1:-1] + y
+        index += len(x1)-index1-2
+    elif index2+1 < len(y21):
+        # compute the linear interpolations values
+        y = y11[index1] + (y12[index1]-y11[index1]) * \
+            (x2[index2+1:-1]-x1[index1]) / \
+            (x1[index1+1]-x1[index1])
+        x_new[index+1:index+1+len(x2)-index2-1] = x2[index2+1:]
+        y1_new[index+1:index+1+len(y21)-index2-1] = y21[index2+1:] + y
+        y2_new[index:index+len(y22)-index2-1] = y22[index2:-1] + y
+        index += len(x2)-index2-2
+    else:  # both arrays reached the end simultaneously
+        # only the last x-value missing
+        x_new[index+1] = x1[-1]
+    # finally, the end value for the last interval
+    y2_new[index] = y12[-1]+y22[-1]
+    # only use the data that was actually filled
+    return x_new[:index+2], y1_new[:index+1], y2_new[:index+1]
+
+
+############################################################
+# add_discrete_function_python
+############################################################
+def add_discrete_function_python(x1, y1, mp1, x2, y2, mp2):
+
+    x_new = np.empty(len(x1) + len(x2))
+    y_new = np.empty_like(x_new)
+    mp_new = np.empty_like(x_new)
+    x_new[0] = x1[0]
+    index1 = 0
+    index2 = 0
+    index = 0
+    while (index1+1 < len(y1)) and (index2+1 < len(y2)):
+        if x1[index1+1] < x2[index2+1]:
+            index1 += 1
+            index += 1
+            x_new[index] = x1[index1]
+            y_new[index] = y1[index1]
+            mp_new[index] = mp1[index1]
+        elif x1[index1+1] > x2[index2+1]:
+            index2 += 1
+            index += 1
+            x_new[index] = x2[index2]
+            y_new[index] = y2[index2]
+            mp_new[index] = mp2[index2]
+        else:  # x1[index1+1] == x2[index2+1]
+            index1 += 1
+            index2 += 1
+            index += 1
+            x_new[index] = x1[index1]
+            y_new[index] = y1[index1] + y2[index2]
+            mp_new[index] = mp1[index1] + mp2[index2]
+    # one array reached the end -> copy the contents of the other to the end
+    if index1+1 < len(y1):
+        x_new[index+1:index+1+len(x1)-index1-1] = x1[index1+1:]
+        y_new[index+1:index+1+len(x1)-index1-1] = y1[index1+1:]
+        mp_new[index+1:index+1+len(x1)-index1-1] = mp1[index1+1:]
+        index += len(x1)-index1-1
+    elif index2+1 < len(y2):
+        x_new[index+1:index+1+len(x2)-index2-1] = x2[index2+1:]
+        y_new[index+1:index+1+len(x2)-index2-1] = y2[index2+1:]
+        mp_new[index+1:index+1+len(x2)-index2-1] = mp2[index2+1:]
+        index += len(x2)-index2-1
+    # else:  # both arrays reached the end simultaneously
+    #     x_new[index+1] = x1[-1]
+    #     y_new[index+1] = y1[-1] + y2[-1]
+    #     mp_new[index+1] = mp1[-1] + mp2[-1]
+
+    y_new[0] = y_new[1]
+    mp_new[0] = mp_new[1]
+
+    # the last value is again the end of the interval
+    # only use the data that was actually filled
+    return x_new[:index+1], y_new[:index+1], mp_new[:index+1]
+